主页 / 问题 / 928621
Accepted
Павел
Asked:2020-01-05 17:06:44 +0000 UTC2020-01-05 17:06:44 +0000 UTC

每月计数

  • 772

Google表格中有一张费用表，它有两列：

  • sum（C列数字格式）
  • 日期（D 栏“2018 年 12 月 11 日”）

每月的开支需要汇总。

我正在尝试使用该功能SUMIF：SUMIF(D:D;Условие;C:C)。这种情况的整个问题。如果您将特定日期放在条件中的引号中，例如“2018 年 12 月 11 日”，那么一切正常，每天的金额就会计算出来。这表明该公式将日期视为字符串并将其与字符串进行比较。似乎您可以放置​​一个模板来代替该行。但！如果我在公式中输入“??.12.2018”或“*.12.2018”而不是“12.11.2018”来查找 12 月的金额，则计算结果为 0。

我将不胜感激。

google-spreadsheet

1 个回答

  1. Best Answer

    简而言之，那么

    =SUMIF(ARRAYFORMULA(TEXT(D2:D;"DD.MM.YYYY"));"*12.2018";C2:C)

    SUMIF

    给定数字的金额。假设有L1某个日期，那么我们可以计算这个日期的金额

    =SUMIF(
  ARRAYFORMULA(MONTH(D2:D33)&YEAR(D2:D33));
  MONTH(L1)&YEAR(L1);
  C2:C
)

    与第一个类似，但有格式转换

    =SUMIF(
  ARRAYFORMULA(TEXT(D2:D;"MMYYYY"));
  TEXT(L1;"MMYYYY");
  C2:C
)

    通常您需要将结果直接显示在所需行的对面，那么最好使用组合ARRAYFORMULA(SUMIF)

    =ARRAYFORMULA(IF(
 LEN(C2:C);
 SUMIF(MONTH(D2:D);MONTH(D2:D);C2:C);
 ""
))

    SUMIFS

    该函数具有相似的性质SUMIFS。适用于日期和转换为文本：

    =SUMIFS(
  C2:C33;
  ARRAYFORMULA(MONTH(D2:D33)&YEAR(D2:D33));
  MONTH(L1)&YEAR(L1)
)

    SUMPRODUCT

    从技术上讲，它应该是基于解决方案的SUMPRODUCT首要解决方案，并且是主要解决方案，因为。这个公式是电子表格处理器含义的拟人化

    =SUMPRODUCT((YEAR(D2:D)=YEAR(L1))*(MONTH(D2:D)=MONTH(L1))*C2:C)

    QUERY

    最常见的选项之一是使用QUERY.

    例如，

    =QUERY(
  ARRAYFORMULA({TEXT(D2:D;"YYYY-MM")\C2:C});
  "select Col1,sum(Col2) where Col1<>'1899-12' " &
  "group by Col1 label Col1'Дата',sum(Col2)'Сумма'"
)

    FILTER

    表格中最强大的功能。如果日期还在，L1那么

    =SUM(FILTER(C2:C33;MONTH(D2:D33)=MONTH(L1)))

    我的首选

    =SUM(FILTER(C2:C33;TEXT(D2:D33;"MMYYYY")=TEXT(L1;"MMYYYY")))

    表中的示例

    笔记

    您应该始终牢记，月份可以逐年重复，如果数据在不同年份的范围内，则值得考虑。

    • 1

相关问题